/**
* Quality measure of two stacks of images assumed to be from opposite angle views 
* using gray-level standard deviation
* @author Rosa Huaman <rosavcalm@hotmail.com> 
*/


// Functions to get the maximum and minimum
function getMax(a,b) { 
 	max=a[0]; 
    for (i=0; i<a.length; i++) { 
    	max = maxOf(max,a[i]); 
        max = maxOf(max,b[i]);  
    } 
   	return max; 
} 

function getMin(a,b) { 
 	min=a[0]; 
    for (i=0; i<a.length; i++) { 
    	min = minOf(min,a[i]); 
        min = minOf(min,b[i]);  
    } 
   	return min; 
} 

// Open stack from first view
run("Set Measurements...", "standard redirect=None decimal=7");
run("Open...");
imgid1=getImageID();

// Computes gray-level standard deviation through Z
arr1=newArray(nSlices);
setTool("rectangle");
waitForUser("Please draw the rectangle for focus measure. Click OK when you are done.");
run("Set Measurements...", "standard redirect=None decimal=7");
for(i=1; i<(nSlices+1); i++){
	setSlice(i);
	run("Measure");
	arr1[i-1]=getResult("StdDev", i-1);
}
selectWindow('Results');
run("Close"); 

// Open stack from second view
run("Open...");
imgid2=getImageID();
selectImage(imgid2);

// Computes gray-level standard deviation through Z
arr2=newArray(nSlices);
setTool("rectangle");
waitForUser("Please draw the rectangle for focus measure. Click OK when you are done.");
run("Set Measurements...", "standard redirect=None decimal=7");
for(i=1; i<(nSlices+1); i++){
	setSlice(i);
	run("Measure");
	arr2[i-1]=getResult("StdDev", i-1);
}
selectWindow('Results');
run("Close"); 

// Normalization of values
maxtot=getMax(arr1,arr2);
mintot=getMin(arr1,arr2);
for (i=0; i<arr1.length; i++){
	arr1[i]=(arr1[i]-mintot)/(maxtot-mintot);
	arr2[i]=(arr2[i]-mintot)/(maxtot-mintot);
}	


// Plot of the gray-level std from the two stacks
xarr = newArray(nSlices);
for (i=0; i<arr1.length; i++){
	xarr[i]=i+1;
}
Plot.create("Standard Deviation","Slices", "Gray-level std"); 
Plot.setLimits(0, arr1.length, 0, 1); 
Plot.setColor("red"); 
Plot.add("line", xarr, arr1); 
Plot.setColor("green"); 
Plot.add("line", xarr, arr2);
Plot.setLegend("View1\nView2") 
Plot.update();